'Alan Kaplan, alan.kaplan@va.gov
'Demonstrates incorrect reporting of medialoaded and signature properties 
'of Win32_Disk Drive for non admin users

Dim WshShell
Set wshShell = WScript.CreateObject("WScript.Shell")
strComputer = wshShell.ExpandEnvironmentStrings("%COMPUTERNAME%")
strUserName = wshShell.ExpandEnvironmentStrings("%USERNAME%")

WScript.Echo "=========================================="
WScript.Echo "Computer: " & strComputer

If ISAdmin = True Then 
	WScript.Echo strUserName & " is an administrator"
Else
	WScript.Echo strUserName & " is not an administrator"	
End If 

Set oWMI = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
Set ColOS = oWMI.ExecQuery("SELECT Caption, csdversion FROM Win32_OperatingSystem")

For Each objOS in ColOS
	 Osver = objOS.caption & Space(1) & objOS.csdversion
	 WScript.Echo Osver
Next

WScript.Echo "=========================================="

Set colItems = oWMI.ExecQuery("SELECT * FROM Win32_DiskDrive", ,48)

For Each objItem In colItems
   WScript.Echo "Caption: " & objItem.Caption
   WScript.Echo "MediaLoaded: " & objItem.MediaLoaded
   WScript.Echo "Signature: " & objItem.Signature
Next


Function ISAdmin()	' the FSO way
	On Error Resume Next
	Dim fso, strSysFolder, strFile, oFile
	Set fso = CreateObject("Scripting.FileSystemObject")
	strSysFolder = fso.GetSpecialFolder(1) 'System Folder
	strFile = strSysFolder & "\IsAdmin.txt"
	Set oFile = fso.CreateTextFile(strFile,True)
	If Err <> 0 Then 
		Err.Clear
		ISAdmin = False
	Else
		oFile.Close
		ISAdmin = True
		'Cleanup file 
		fso.DeleteFile(strFile)
	End If
	On Error GoTo 0
End Function